initial

Reference/AAS+StrafeArrest/AAS_Stop.yolol

@@ -0,0 +1,40 @@
+r=4000 p=99 a=1 //turn on+off AAS to update init values
+goto2+:AAS //Non-assigning wait loop
+:C=:AAS*r>(:AL+:AR+:AU+:AD) if:Cthen:Crus=a :CF=0 goto4endgoto3*:AAS
+c=:AAS*r>(:AL+:AR+:AU+:AD) :CB=p*c :CF=:FS*(1-c) :MAL=0-c goto3+c
+goto3 //Fallthrough case. Maybe CF/B=0 to prevent errors?
+//Sets fwd to 0 and bwd to max if a sector is colliding
+//Resets fwd to original value when the obstruction ends.
+//OLD line 4 for comparison
+if:AAS*r>(:AL+:AR+:AU+:AD)then:CB=p goto4end :CB=0 :CF=:FS goto3
+
+//Dependencies
+//NavSuite LeverCenterCenterValue computer controls. :CF, :CB, :FS
+//LeverCenteringSpeed on forward stick set to Crus
+//MoveArrest_Lat system with :MAL chipwait
+
+
+
+
+
+//Original by Thaccus
+r=4000 p=99 a=1 //turn on+off AAS to update init values
+goto2+:AAS //Non-assigning wait loop
+:C=:AAS*r>(:AL+:AR+:AU+:AD) if:Cthen:Crus=a :CF=0 endgoto(3+:C)*:AAS
+c=:AAS*r>(:AL+:AR+:AU+:AD) :CB=p*c :CF=:FS*(1-c) :MAL=-c goto3+c
+goto1
+//Sets fwd to 0 and bwd to max if a sector is colliding
+//Resets fwd to original value when the obstruction ends.
+//OLD line 4 for comparison
+if:AAS*r>(:AL+:AR+:AU+:AD)then:CB=p goto4end :CB=0 :CF=:FS goto3
+
+//Dependencies
+//NavSuite LeverCenterCenterValue computer controls. :CF, :CB, :FS
+//LeverCenteringSpeed on forward stick set to Crus
+//MoveArrest_Lat system with :MAL chipwait
+
+
+
+
+
+//Original by Thaccus

Reference/AAS+StrafeArrest/AAS_Strafe.yolol

@@ -0,0 +1,20 @@
+r=1000 p=100 n=-p :CV=0 :CH=0//r=AU/AD/AL/AR p=FcuInputRange
+goto2+:AAS //Non-assigning wait loop
+z/=:C a=:AL<r b=:AD<r :CH=p*a+n*(:AR<r-a) :CV=p*b+n*(:AU<r-b)
+if(:StopLat+:c)<1then:CV=0 :CH=0 endgoto3*:AAS
+goto1
+//Designed to be used with AAS_Stop, MovementArrest, and ESTOP systems
+//Turn the AAS on and then off to re-init line1 values
+
+//Dependencies
+//NavSuite LeverCenterCenterValue computer controls.
+//AAS_Stop chip for :C output
+//StopLat Button from MovementArrest system
+
+
+
+
+
+
+
+//Original by Thaccus

Reference/AAS+StrafeArrest/MovementArrest_Fwd.yolol

@@ -0,0 +1,19 @@
+y=-5 yd=3 t=0.4 m=0.001 f=.01 b=.5
+goto2+:ESTOP
+:Crus=1 :AAS=0 :NAV=0 :StopLat=1 :MAL=0
+c=y*:RZ+yd*((:RZ-a)/t) a=:RZ :CF=c*f :CB=-c*b goto5-2*:ESTOP
+:CF=0 :CB=0 :StopLat=0 goto1
+
+
+
+
+
+
+
+
+
+//Dependencies
+//LD/CLF Translation Sensor :RZ
+//NavSuite LeverCenterCenterValue computer controls. :CF, :CB
+//MovementArrest_Lat chip with chipwait named :MAL
+//:ESTOP and :StopLat buttons

Reference/AAS+StrafeArrest/MovementArrest_Lat.yolol

@@ -0,0 +1,20 @@
+y=-2 yd=-.5 x=2 xd=.5 t=0.4 :CV=0 :CH=0
+goto2+:StopLat
+:CV=y*:RY+yd*((:RY-a)/t) :CH=x*:RX+xd*((:RX-b)/t) a=:RY b=:RX
+goto3*:StopLat
+goto5 //error catch if no button. Set goto1 to reset.
+
+
+
+
+
+
+
+
+//Name chipwait field :MAL for ESTOP/AAS integration.
+
+//Dependencies
+//LD/CLF Translation Sensor :RX :RY
+//NavSuite LeverCenterCenterValue computer controls. :CH, :CV
+//:StopLat button
+

Reference/AAS+StrafeArrest/readme.md

@@ -0,0 +1,11 @@
+# AAS+StrafeArrest+EmergencyStop Package
+
+This set 4 chips uses the LDTS to improve on the longstanding asteroid avoidance regime. It does so by arresting lateral motion after the AAS finishes dodging so that you do not drift into new obstructions. As a bonus, the same code can be used to create an emergency stop button that will counter all motion regardless of facing until the ship comes to a full stop. I have included in this upload a small ship that was built using the newest NavSuite release candidate set and includes this new feature set.
+
+I am using PD control and you can tune them to your liking through the x/y and xd/yd variables in either MovementArrest chip.
+
+The strafe arrest system wants to affect the same control fields that AAS does and I have remade the AAS code such that it no longer assigns to computer controls unless it detects something. Unfortunately I could not find a way to do that elegantly on the single line that was the old AAS_Strafe and as such this new version is a two line operation. If anyone wants to have a go at compacting the behavior back down to one line I would be happy to outline the problem and desired behavior.
+
+On a happier note: this version has a control hierarchy. ESTOP always has priority and pressing the big red stop button turns off any other computer controls Like AAS/NAV/Cruise. AAS is next in line priority wise and will take control during any avoidance action. Finally and should nothing else take priority, the strafe arrest code will ensure that you are not moving laterally. 
+
+Strafe arrest(being the last in line) is suspended via chipwaiting during any avoidance action. I heard that this may affect LEQ systems and I will be testing this claim during the system's stay here in the WIP world. To be clear this is most definitely WIP and will be undergoing extensive testing before it ever comes to the NavSuite. If you would like to be part of testing the next generation of avoidance, I welcome any feedback you come up with. If you just want stability and things that you know work, I respect that and recommend you stick to the AAS included in the current release until this gets more thoroughly vetted.

Reference/AAS_Stop.yolol

@@ -0,0 +1,20 @@
+r=4000 p=99 a=1 :c=0 //turn on+off AAS to update init values
+goto2+:AAS //Non-assigning wait loop
+:C=:AAS*r>(:AL+:AR+:AU+:AD) if:C then:Crus=a :CF=0 end goto(3+:C)*:AAS
+c=:AAS*r>(:AL+:AR+:AU+:AD) :CB=p*c :CF=:FS*(1-c) :ACN=-c goto3+c
+goto1
+//Sets fwd to 0 and bwd to max if a sector is colliding
+//Resets fwd to original value when the obstruction ends.
+
+//OLD line 4 for comparison
+if:AAS*r>(:AL+:AR+:AU+:AD)then:CB=p goto4end :CB=0 :CF=:FS goto3
+
+//Dependencies
+//NavSuite LeverCenterCenterValue computer controls. :CF, :CB, :FS
+//LeverCenteringSpeed on forward stick set to Crus
+//MoveArrest_Lat system with :ACN chipwait
+
+
+
+
+//Original by Thaccus

Reference/AAS_Strafe.yolol

@@ -0,0 +1,20 @@
+r=1000 p=100 n=-p :CV=0 :CH=0 //r=AU/AD/AL/AR p=FcuInputRange
+goto2+:AAS //Non-assigning wait loop
+z/=:C a=:AL<r b=:AD<r :CH=p*a+n*(:AR<r-a) :CV=p*b+n*(:AU<r-b) goto4-:c
+if(:AN+:c)<1then:CV=0 :CH=0 endgoto3*:AAS
+goto1
+//Designed to be used with AAS_Stop, MovementArrest, and ESTOP systems
+//Turn the AAS on and then off to re-init line1 values
+
+//Dependencies
+//NavSuite LeverCenterCenterValue computer controls.
+//AAS_Stop chip for :C output
+//:AN Button from MovementArrest system
+
+z/=:AAS a=:AL<r b=:AD<r :CH=p*a+n*(:AR<r-a) :CV=p*b+n*(:AU<r-b) goto3
+r>(:AL+:AR+:AU+:AD)
+
+
+
+
+//Original by Thaccus

Reference/Approach.yolol

@@ -0,0 +1,19 @@
+s=15 t=15 m=1000 g=0.800 ib=4 p=0 i=0 x=ib+s u=0
+:cdc=2-:cd goto(4-:CD)*:APRCH*(:AU<m)
+Kp=0.038 Ki=0.001 Kd=5.4 f=0.3 n=300 Kd*=1-f l=:AU-s goto5 //NSZ
+Kp=0.038 Ki=0.001 Kd=5.4 f=0.3 n=500 Kd*=1-f l=:AU-s goto5 //SZ
+e=:AU-s p=e p-=(e>n)*(e-n) d=(l-e)*Kd+d*f i+=e*Ki*(:AU<x) r=u/t u+=u<t
+l=e z/=:Aprch*(:AU<m)*(d*d>g+e*e>5) :CF=(Kp*p+i)*r :CB=(d-i)*r goto5
+if((d*d>g+e*e>5)*:APRCH)<1 then :APRCH=0 :CF=0 :CB=0 goto1end goto5
+
+//Improved PID - Approximated Profiled Motion PID - VER 2.1
+// github.com/GameName-Darkyshadow/Starbase
+// tips by in game mail are not necessary but appreciated
+// Tuning Parameters explained on Github with Manual
+// by: Darkyshadow
+
+
+
+
+
+

Reference/Approach/ApproachPID.yolol

@@ -0,0 +1,14 @@
+s=10 Kp=0.3 Ki=0.01 Kd=4 t=3 m=1000 g=1/m p=0 goto1+:Approach>0
+r=:RFD e=r-s d=e-p i+=e/(d-g) i/=2 o=Kp*e+Ki*i+Kd*d p=e r*=r<m
+z/=:Approach*r*(d*d>g+e*e>1) :FcuForward=o/t :FcuBackward=-o*t goto2
+:Approach=0 :FcuForward=0 :FcuBackward=0 goto1
+
+// PID approach uses a proportional-integal-derivative controller to
+// output FCU values appropriate to the distance and current speed.
+// It has several tunables:
+// s (setpoint)      the distance we want to get to
+// Kp (proportional) how much we factor in our current distance
+// Ki (integral)     factor of how long we've been at our distance
+// Kd (derivative)   factor of prediction of where we'll be in future
+// t (thrust diff)   account for disparity in forward/rev thrust power
+// CREDIT TO WHITESTRAKE

Reference/Approach/README.md

@@ -0,0 +1,2 @@
+This is the MutleyX Approach script you find on TriFin and other ships
+Needs a rangefinder and approach button.

Reference/Approach/approach.yolol

@@ -0,0 +1,17 @@
+// Approach ahead - Mutleyx
+:Approach=0 :range=0 od=0 oa=0
+a=:Approach ifa!=oa thenoa=a :range=a end goto3+a
+d=:RangeAhead ifd!=500thengoto6end
+:FcuForward=0 :FcuBackward=0 goto3
+ifd>15 and d<20thengoto9end
+done=0 cd=17.5-d dx=od-cd od=cd adj=-(cd-4.5*dx) goto15
+
+:FcuForward=0 :FcuBackward=0
+done++ ifdone>10then:Approach=0end
+goto2*:Approach+2
+
+
+
+ifadj>d thenadj=d end :FcuForward=0 :FcuBackward=0
+ifadj<0then:FcuBackward=-adj*0.5else:FcuForward=adj*0.25end
+if:Approach thengoto4elsegoto9end

Reference/ArrestChipForward(ACF).yolol

@@ -0,0 +1,20 @@
+y=-12 yd=-4 t=0.4 m=0.001 f=.045 b=1
+e=:AN goto2+:ESTOP
+:AN=1 :ACN=0 :Crus=10 :AAS=0 :NAV=0 :APRCH=0 :FS=0
+c=y*:RZ+yd*((:RZ-a)/t) a=:RZ :CF=c*f :CB=-c*b goto5-2*:ESTOP
+:CF=0 :CB=0 :Crus=1 :AN=e goto1
+
+
+
+
+
+
+
+
+
+//Dependencies
+//LD/CLF Translation Sensor :RZ
+//NavSuite LeverCenterCenterValue computer controls. :CF, :CB
+//MovementArrest_Lat chip with chipwait named :ACN
+//:ESTOP and :AN control buttons
+//By Thaccus

Reference/ArrestChipNormal(ACN).yolol

@@ -0,0 +1,20 @@
+y=10 a=6 x=-10 b=-6 t=0.2 :CV=0 :CH=0
+goto2+:AN
+:CV=y*:RY+a*((:RY-c)/t) :CH=x*:RX+b*((:RX-d)/t) c=:RY d=:RX goto3*:AN
+
+goto5 //error catch. Set goto1 to reset.
+
+
+
+
+
+
+
+
+//Name chipwait field :ACN for ESTOP/AAS integration.
+
+//Dependencies
+//LD/CLF Translation Sensor :RX :RY
+//NavSuite LeverCenterCenterValue computer controls. :CH, :CV
+//:AN Arrest Normal button
+//Credit to Firestar99

Reference/Autonomy.yolol

@@ -0,0 +1,20 @@
+k=1000 t=.6 n="\n" d="Km"+n z=10 x=z-1 f=:fuel p=:propellant
+a=n+"Fuel Range:"+n b="Prop Range:"+n c=n+"Not Moving"
+fl=f f=(:fuel+f*x)/z fd=fl-f s=(:SPD+s*x)/z rf=f/fd*s*t/k
+pl=p p=(:propellant+p*x)/z pd=pl-p rp=p/pd*s*t/k
+if:Spdthen:estrange=a+rf/k*k+d+b+rp/k*k+d else:estrange=c endgoto3
+
+
+
+//z is smoothing, higher numbers mean less jumpy ranges but they take
+//longer to stabilize.
+
+//Requires text panel named :Range
+//Requires FuelChamberFuel named :Fuel 
+//requires GasNetworkStoredResource named :Propellant
+
+
+
+
+
+By HappyTrigger and Thaccus

Reference/Autopilot.yolol

@@ -0,0 +1,20 @@
+if1-:Nav theng=0 f=0 goto1end 
+l=0.04 pt=100 yt=100 rt=5 ep=1.05 ed=3000 et=3000 w=26 p=2 a=13
+xD=:WX-:X yD=:WY-:Y zD=:WZ-:Z Dt=((xD)^2+(yD)^2+(zD)^2)^.5
+:AAS=g :AN=g iff<1thenx0=:X y0=:Y z0=:Z Do=Dt f=1 r=0 end
+da=((:X-x0)^2+(:Y-y0)^2+(:Z-z0)^2)^.5 dx=(Do-da)*ep+ed s=Dt>dx
+ifs>0then:CF=0 if:SPD<1thenf=0 g=0 s=0 goto1endend
+ifDt<et then:Nav=0 :CF=0 :FS=0 end ifg thengoto1end
+n="\n" :DD=n+(Do-da)+n+Dt+n+"ly:"+:LY+" lx:"+:LX+" l:"+l+" g:"+g
+c1=:LX>-l c2=:LX<l c3=:LY>-l c4=:LY<l lz=:LZ<0 ry=c1+c2 rx=c3+c4
+ifc1*c2*c3*c4*(1-lz)theng=1 :FS=:MaxFF :CF=:MaxFF :Crus=1 goto1end
+if(lx==:LX)*(ly==:LY)then:CR=rt t=0 gotoaend
+ifry+rx+lz then:CP=:LY*pt :CY=:LX*yt+yt*lz t=0 end
+ift>pthen:CR=0 :CP=0 :CY=0 endift<wthent++gotoaend lx=:LX ly=:LY goto1
+
+
+
+
+
+
+//Original by Fixerid. Modified by Thaccus

Reference/Avoidance.yolol

@@ -0,0 +1,5 @@
+goto :Avoid*((:US+:DS+:LS+:RS)<4000)*2
+i=2*(:DS<1000)-:US<1000 :FcuUpDown+=100*i
+i=2*(:LS<1000)-:RS<1000 :FcuRightLeft+=100*i goto (i==0)*4
+:FcuUpDown=0 :FcuRightLeft=0 goto1
+// example of avoidance script

Reference/Buffalo/BuffaloAlarm.yolol

@@ -0,0 +1,14 @@
+if:AlarmOveride==1then:SoundOn=0 :RedLight=0 goto1end
+if:DurErr>0thenalarm=1 :SndT=8 alm="Durability" goto5elsealarm=0end
+if:FuelCheck<500thenalarm=1 :SndT=4 alm="Fuel" goto5elsealarm=0end
+if:Propellant<500thenalarm=1 :SndT=6 alm="Prop" goto5elsealarm=0end
+:SoundOn=0+alarm ifalarm then:RedLight=1-:RedLight else:Redlight=0end
+ifalarm!=1then:Info="\nWarpClass: "+:WarpClass goto1 end
+if alm=="Durability" then alm+=" "+:DurErr end :Info="\n"+alm goto 1
+
+
+// This replaces the 2 individual alarm chips.
+// Also change priority on the sound device above seat to 1 and
+// radius to 50.  Also change DurabilityErrors to DurErr on ship 
+// monitor at top of YOLOL rack stack.   You can // comment out any
+// alarms you dont care about (lines 2-4)

Reference/Buffalo/BuffaloApproachOld.yolol

@@ -0,0 +1,17 @@
+// Approach ahead - Mutleyx
+:Approach=0 :range=0 od=0 oa=0
+a=:Approach ifa!=oa thenoa=a :range=a end goto3+a
+d=:RangeAhead ifd!=500thengoto6end
+:FcuForward=0 :FcuBackward=0 goto3
+ifd>15 and d<20thengoto9end
+done=0 cd=17.5-d dx=od-cd od=cd adj=-(cd-4.5*dx) goto15
+
+:FcuForward=0 :FcuBackward=0
+done++ ifdone>10then:Approach=0end
+goto2*:Approach+2
+
+
+
+ifadj>d thenadj=d end :FcuForward=0 :FcuBackward=0
+ifadj<0then:FcuBackward=-adj*4else:FcuForward=adj*0.15end
+if:Approach thengoto4elsegoto9end

Reference/Buffalo/BuffaloApproachPID.yolol

@@ -0,0 +1,14 @@
+s=15 Kp=0.28 Ki=0.01 Kd=4 t=1.25 m=1000 g=1/m p=0 goto1+:Approach>0
+r=:RFD e=r-s d=e-p i+=e/(d-g) i/=2 o=Kp*e+Ki*i+Kd*d p=e r*=r<m
+z/=:Approach*r*(d*d>g+e*e>1) :FcuForward=o/t :FcuBackward=-o*t goto2
+:Approach=0 :FcuForward=0 :FcuBackward=0 goto1
+
+// PID approach uses a proportional-integal-derivative controller to
+// output FCU values appropriate to the distance and current speed.
+// It has several tunables:
+// s (setpoint)      the distance we want to get to
+// Kp (proportional) how much we factor in our current distance
+// Ki (integral)     factor of how long we've been at our distance
+// Kd (derivative)   factor of prediction of where we'll be in future
+// t (thrust diff)   account for disparity in forward/rev thrust power
+// Credit to Whitestrake

Reference/Buffalo/BuffaloDoors.yolol

@@ -0,0 +1,7 @@
+t=0 timer=40 if :Battery < 2000 then goto4 end
+if :R_Door+:L_Door then goto3 end goto1
+if t<timer then t++ goto 3 else :R_Door=0 :L_Door=0 goto1 end
+:R_Door=1 :L_Door=1 :ENGDoor=1 goto1
+
+// This replaces the door chip.  Set timer to how long you want
+// doors to stay open before closing.

Reference/Buffalo/BuffaloMinerPositioning.yolol

@@ -0,0 +1,20 @@
+if:Static+:Mine==0thengoto10end
+if:Static thengoto9end if(:LTCR==18.7)*(:LTCP==-7)thengoto11end goto2
+if:Static thengoto9end if(:LTCR==18.7)*(:LTCP==0)thengoto12end goto3
+if:Static thengoto9end if(:LTCR==18.7)*(:LTCP==-14)thengoto13end goto4
+if:Static thengoto9end if(:LTCR==6.7)*(:LTCP==-14)thengoto14end goto5
+if:Static thengoto9end if(:LTCR==6.7)*(:LTCP==0)thengoto15end goto6
+if:Static thengoto9end if(:LTCR==30.7)*(:LTCP==0)thengoto16end goto7
+if:Static thengoto9end if(:LTCR==30.7)*(:LTCP==-14)thengoto10end goto8
+goto 10
+:LTP=-7 :RTP=-7 :LTR=18.7 :RTR=-18.7 :BTR=0 :BTP=-7 goto1 //Default
+:LTP=0 :RTP=0 :BTP=-14 goto3 //Up
+:LTP=-14 :RTP=-14 :BTP=0 goto4 //Down
+:LTR=6.7 :RTR=-30.7 :BTR=12 goto5 //Left
+:LTP=0 :RTP=0 :BTP=-14 goto6 //Up
+:LTR=30.7 :RTR=-8.7 :BTR=-12 goto7 //Right
+:LTP=-14 :RTP=-14 :BTP=0 goto8//Down
+// :LTY and :RTY are left and right upper turret rotation
+// :BTP is bottom turret pitch.  :Mine is mining button
+// :Static is static button (so they dont move)
+// :LTCP/LTCR are current pitch and rotation of left turret

Reference/Buffalo/BuffaloMinerSafety.yolol

@@ -0,0 +1,13 @@
+PPchk=(:BTCP>=-17)*(:BTCP<=3)*(:LTCP>=-15)*(:RTCP>=-15)
+Rchk=(:LTCR<=40)*(:LTCR>=0)*(:RTCR<=0)*(:RTCR>=-40)
+:Pchk=(PPchk*Rchk) b="\n" 
+if:Mine then:turtle=10end goto1
+//Ang=b+"B:"+:BTCR+" "+:BTCP+b
+//:Ang=Ang+"L:"+:LTCR+" "+:LTCP+b+"R:"+:RTCR+" "+:RTCP+b+"Pchk:"+:Pchk
+
+// Uncomment the two lines above if you want to see angles on your
+// turrets on a screen named :Ang.  Movce the line 4 below them.
+// :BTCP is bottom turret current pitch, :LTCP and :RTCP are for 
+// top turrets.  :Mine is mine button, :turtle is turtle button
+// :PChk is store on memory chip (or other device)
+// This, positioning and Control mining chips replace the original.

Reference/Buffalo/BuffaloNavLight.yolol

@@ -0,0 +1,8 @@
+if:insideSafeZone==0then:Nav_Lights=0 :NavRed=0 :NavGreen=0 goto1end
+if:Nav_Lights*:insideSafeZone thengoto3elsegoto1end
+if:insideSafeZone thenift<5thent++ goto3endelsegoto1end
+t=0 :NavRed=1-:NavRed :NavGreen=1-:NavGreen goto2
+
+// This replaces the original navlights chip. no new fields.
+// auto turns off nav lights if you cross in unsafe and doesnt allow
+// them on while in unsafe.

Reference/Buffalo/BuffaloScanner.yolol

@@ -0,0 +1,22 @@
+a="Valkite" wa=8.08 b="Bastium" wb=wa c="Ajatite" wc=6.31 d="Ice"
+wd=6.78 e="Vokarium" we=wd f="Nhurgite" wf=wc g="Surtrite" wg=wf
+h="Charodium" wh=11.25 i="Exorium" wi=14.25 j="Aegisium" wj=7.67
+k="Arkanium" wk=4.31 l="Karnite" wl=8.08 m="Kutonium" wm=7.36
+n="Lukium" wn=15.25 o="Corazium" wo=9.95 p="Ymrium" wp=8.78
+q="Xhalium" wq=wc scn=""
+r="\n" s=" Ore" t=" Crystal" u=100 v=" Stks" scn=""
+if:Scanner==0then:Scn="Off"+r+scn goto8end :Scan=1 :Scn="Scan.."+r+scn
+:ind=0 if:V==0then:Scn="Scan."+r+scn goto8end
+z=:M-s-t V1=:V/1728 V1=(V1+0.05)/u*u L1=z+r+V1+v goto14
+:ind=1 z=:M-s-t V2=:V/1728 V2=(V2+0.05)/u*u L2=r+z+r+V2+v goto14
+P=V2/V1*100 Scn=L1+L2+r+P+"%"+s+r+mt/1000/u*u+" mt" :Scn="Final"+r+scn
+mt=0 :ind=0 :V=0 goto8
+:Scn="Calc"+r+scn
+wt=(z==a)*wa+(z==b)*wb+(z==c)*wc+(z==d)*wd+(z==e)*we+(z==f)*wf
+wt+=(z==g)*wg+(z==h)*wh+(z==i)*wi+(z==j)*wj+(z==k)*wk+(z==l)*wl
+wt+=(z==m)*wm+(z==n)*wn+(z==o)*wo+(z==p)*wp+(z==q)*wq
+mt+=wt*:V goto11+:ind
+// Scanner is first field name on Button and :Scanner
+// Scn is first field name of Text Display
+// On Scanner, rename Volume field to V, Material field to M, and
+// Index field to ind 

Reference/Buffalo/BuffaloTransponder.yolol

@@ -0,0 +1,10 @@
+i=:insideSafeZone :Safezone_B=i
+if i then :Safe_C=2 else :Safe_C=1 end
+if i then :Tran_C=2 a=0 b=0 else :Tran_C=1 a=1 end
+if(not b)*a then :transponder=0 b=1 end
+if(not a)*b then a=0 end goto1
+
+// No new button names.  Auto turns off transponder if cross into
+// unsafe.  Sets the rectangular button colors based on unsafe.
+// will allow transponder to be turned back on manually if desired
+// in unsave.

Reference/Buffalo/BuffalonMineControl.yolol

@@ -0,0 +1,11 @@
+if:Mine*:PChk then:MLT=1-:MLT :CL=1-:CL goto1else:MLT=0 :CL=:COLL end
+if:PChk==0then:LTP=-7 :RTP=-7 :LTR=18.75 :RTR=-18.75 :BTP=-7end goto1
+
+
+// :Mine is mining button, :Pchk is on a memory chip or other device
+// :MLT is the first field on all lasers.  :CL is first on collectors
+// :COLL is collector button.
+// :RTP, :LTP, :BTP is the first field on the pitch of the turrets
+// for right, left and bottom lasers.
+
+// This, Safety and positioning mining chips replace the original.

Reference/Buffalo/README.md

@@ -0,0 +1,12 @@
+These files modify or replace existing YOLOL files on a Buffalo for more functionality.
+Files are commented.  Comments are not required to be on the chips of course.
+
+### Mining System
+
+The mining system uses 3 basic chips, one for Control, one for Safety and one for Positioning.
+I sometimes change the positioning, but currently you start with your aim point in middle of rock,
+lasers will then go up, down, left, up, right, down, center and repeat.  At 15m from rock it seems to
+get most of it.
+
+You can see the pictures of my installation and of the turrets Rotation and Pitch settings in the
+images folder here.

Reference/ChomperLiteScripts/ChomperGenerator.yolol

@@ -0,0 +1,11 @@
+b=:BatteryLevel>=9995 G=:Generator gr=:GenRate m=51*(1-:ECO)+101*:CBOS
+m+=33*(:FCUForward>0)*(m==0) ifG<m+b*(m==0+G>m)thenG=m end 
+G+=1*(b!=1)*(G<=gr)*(gr<100) G-=1*b*(G>=gr)*(gr>0) G*=:Shutdown
+:Generator=G :GenRate=:GeneratorUnitRate m=0 goto1
+// b = current battery level
+// G = current generator setting
+// gr = current generator rate (how close to setting)
+// m = minimum battery level, 0 base, 33 if forward engines on,
+//     51 if Eco button off, 101 if Cargo Beams are on
+// G is raised by 1 or lowered by 1 to keep battery charged so long
+// as G is at least minimum.

Reference/ChomperLiteScripts/EngineControl.yolol

@@ -0,0 +1,2 @@
+if:Eco*(:FCUForward>60)then:FCUForward=60end
+if(:BatteryLevel<1500)then:FCUForward=0end goto1

Reference/ChomperLiteScripts/FrameTimer.yolol

@@ -0,0 +1,5 @@
+:CargoFrame=0 :CLF=0 :Delay=25 goto2-:Frame 
+:CargoFrame=1 :CLF=1 :OpenTimer=0 goto2+:Frame
+:OpenTimer++ goto 2-2*(:OpenTimer>:Delay)+:Frame
+
+// :Delay/5 = # of second delay.

Reference/ChomperLiteScripts/RodCount.yolol

@@ -0,0 +1,2 @@
+:TotalRods=:R1+:R2+:R3+:R7+:R8+:R9+:R10+:R11+:R12+:R16+:R17+:R18
+:warningbutton=:TotalRods<300000 goto1

Reference/CompassDisplayPrep.yolol

@@ -0,0 +1,20 @@
+:ka+=.7*(:ka==0) :kz=2-:kr>0 goto2+:kr
+a="+0" b="O1" c=0 d=0 e=0 f=0 g=0 h=0.5 i=1
+j=:X k=:Y l=:Z u=:wx-j v=:wy-k w=:wz-l x=(u*u+v*v+w*w)^h u/=x v/=x
+w/=x :LX=:HX*u+:HY*v+:HZ*w :LY=:IX*u+:IY*v+:IZ*w :LZ=:JX*u+:JY*v+:JZ*w
+f=:ly*3/i+h f=6-f-(3-f)*(f<3)-(-3-f)*(f>-3) g=:lx*5/i+h
+:kx=15-g-(5-g)*(g<5)-(-5-g)*(g>-5) :kz=a+b-:lz<0-a-b :ky=f :kl=x
+i=:ka :ks=((j-c)^2+(k-d)^2+(l-e)^2)^.5/.8 c=j d=k e=l goto3+:kr
+
+
+
+
+:kz=1 c="\n    Read\n  upgrade\ninstruction\n    !!!"
+:k=c+"\n\nmissing :ka" goto12-:kr
+
+
+
+
+
+
+//Credit to Firestar99

Reference/CompassDisplay_Modded.yolol

@@ -0,0 +1,20 @@
+a="" b=" " c="  " d="   " e="    " f="     " g="\n" h="-" i="|"
+j="  |\n" k="-         -" l="\n     |" m=:kz n=:ky goto:kx
+:k=j+g+g+k+g+g+g+t+z+q+m+w+s m=:kx n=:ky goto:kz
+:k=j+g+g+k+g+g+t+u+q+m+l m=:kx n=:ky goto:kz
+:k=j+g+g+k+g+t+u+q+m+g+l m=:kx n=:ky goto:kz
+:k=j+g+g+v+t+q+m+w+x+y+g+g+l m=:kx n=:ky goto:kz
+:k=j+g+t+u+q+m+g+k+g+g+l m=:kx n=:ky goto:kz
+:k=j+t+u+q+m+g+g+k+g+g+l m=:kx n=:ky goto:kz
+:k=o+p+q+m+r+s+g+g+g+k+g+g+l m=:kx n=:ky goto:kz
+t=a q=a w=e x=f u=a z=a p=a s=i v=a y=h o=a r=b goton
+t=a q=a w=d x=f u=b z=b p=a s=i v=h y=h o=a r=b goton
+t=b q=a w=c x=f u=b z=b p=a s=i v=h y=h o=a r=b goton
+t=c q=a w=b x=f u=b z=b p=a s=i v=h y=h o=a r=b goton
+t=d q=a w=a x=f u=b z=b p=b s=i v=h y=h o=a r=a goton
+t=e q=a w=a x=e u=b z=b p=b s=b v=h y=h o=b r=a goton
+t=f q=a w=a x=d u=b z=i p=i s=b v=h y=h o=c r=a goton
+t=f q=b w=a x=c u=b z=i p=i s=b v=h y=h o=c r=a goton
+t=f q=c w=a x=b u=b z=i p=i s=b v=h y=h o=c r=a goton
+t=f q=d w=a x=a u=b z=i p=i s=b v=h y=h o=c r=a goton
+t=f q=e w=a x=a u=b z=i p=i s=a v=h y=a o=c r=a goton

Reference/CompassISAN3In.yolol

@@ -0,0 +1,20 @@
+a="origin_" b=a+"north" c=a+"south" d=a+"east" :tm=b goto2*(1-:IN)+:KR
+a+="west" e=160000 f=8*e g=f*3/13 h=2*e i=h*13/19 j=f*3/19 k=h*13/3
+l=1000000 m=l-:SRB m*=m n=l-:SRF n*=n o=l-:SRD o*=o :tm=c
+p=q r=s t=u
+v=l-:SRB v*=v w=l-:SRF w*=w x=l-:SRD x*=x :tm=d
+:X=(m+v)/f+y/g-z/j :Y=v/h-m/i+(y+z)/k :Z=(y+z-m-v)/e
+y=l-:SRB y*=y q=l-:SRF q*=q s=l-:SRD s*=s :tm=a
+:T=(n+w)/f+p/g-aa/j :U=w/h-n/i+(p+aa)/k :V=(p+aa-n-w)/e
+z=l-:SRB z*=z aa=l-:SRF aa*=aa u=l-:SRD u*=u :tm=b
+:Q=(o+x)/f+r/g-t/j :R=x/h-o/i+(r+t)/k :S=(r+t-o-x)/e goto3*(1-:IN)-:kr
+
+
+
+
+//:ke,:kf,:kg->:SRB, :SRF, :SRD Rear Front down receivers
+//:fx,:fy,:fz->:T,:U,:V Front XYZ
+//:ex,:ey,:ez->:X,:Y,:Z Rear XYZ
+//:gx,:gy,:gz->:Q,:R,:S Down XYZ
+
+//Credit to Firestar99

Reference/CompassOrient.yolol

@@ -0,0 +1,20 @@
+h=.5 goto2-:IN+:KR
+p=:T-:X q=:U-:Y r=:V-:Z m=:Q-:X n=:R-:Y o=:S-:Z s=(m*m+n*n+o*o)^h
+m/=-s n/=-s o/=-s t=(p*p+q*q+r*r)^h p/=t q/=t r/=t y=q*o-r*n z=r*m-p*o
+:JX=p :JY=q :JZ=r :IX=m :IY=n :IZ=o :HX=y :HY=z :HZ=p*n-q*m goto2+:KR
+
+
+//below code moved to CompassDisplayPrep chip
+//:LX=:HX*u+:HY*v+:HZ*w :LY=:IX*u+:IY*v+:IZ*w :LZ=:JX*u+:JY*v+:JZ*w 
+//u=:wx-:X v=:wy-:K w=:wz-:Z x=(u*u+v*v+w*w)^h u/=x v/=x w/=x
+
+
+//For Downward L receiver pattern replace line3 with:
+m/=-s n/=-s o/=-s t=(p*p+q*q+r*r)^h p/=t q/=t r/=t y=q*o-r*n z=r*m-p*o
+//For Upward L receiver pattern replace line3 with:
+m/=s n/=s o/=s t=(p*p+q*q+r*r)^h p/=t q/=t r/=t y=q*o-r*n z=r*m-p*o
+
+
+
+//Globals for Receivers and their coords: SRB(XYZ) SRF(TUV) SRD(QRS)
+//:jx=p :jy=q :jz=r :hx=y :hy=z :hz=a :ix=m :iy=n :iz=o

Reference/CompassOutputXYZ.yolol

@@ -0,0 +1,20 @@
+a=1000 :kr=0 b=0 c=0 d=0 e=0 f=0 g=0 h=""
+i=" POS  ::\n" j=i+"X: " k="\nY: " l="\nZ: " m="\nS: " n=1
+o="m/s\nD: " p="m\n" q=0 r=60 s=1000 t=r*s u="min" v="h "
+
+f=:spd g=:kl d=o+g/a*a+p b=g/f/t*s e=b%r+u q/=b>=r e=b/t*s+v+e
+q/=::==h+n n=0 h=j+:X/a*a+k+:Y/a*a+l+:Z/a*a+m+f/a*a+d+e ::=h goto5
+c=""+:: n=1 goto8+5*(c=="reset")+7*(c=="")
+::=i+"Parsing new Target..." d="98743" w=0 x=-1 b=2
+y=c y-=c-- z=5*(y>4)+2*(d>(d-y)) z+=y>z z+=y>z w+=z*10^x++ goto9+y<0
+aa=1 ify=="-"thenaa=-1 c--end
+ab=ac ac=ad ad=w*aa w=0 x=-1 goto9+3*(--b<0)
+:wx=ad :wy=ac :wz=ab goto5
+:kr=-20 ae=24 d="\nreseting"
+d+="." ::=d goto14-14*(ae--<0)
+d=i+"Streamer mode" ::=d
+c=:: ::=d goto16-11*(c!=d)+8*(c=="reset")
+
+
+
+//Credit to Firestar99

Reference/Cosine (Basic Chip)/README.md

@@ -0,0 +1,19 @@
+# Cosine
+
+This script calculates the cosine of an angle (in degrees) on an **advanced** level Yolol chip.
+
+## Inputs
+
+The input is a single number in the `:i` field.
+
+ - `:i` number (degrees. must be greater than zero)
+
+## Outputs
+
+The output is a single number in the `:o` field.
+
+ - `:o` Cosine(:i)
+
+## Credits
+
+ - Zijkhal#0154

Reference/Cosine (Basic Chip)/cos.yolol

@@ -0,0 +1,7 @@
+// This line sets up some constants. It must be run before the next
+// line. Ensure you are not using the variable names anywhere else
+// in your program.
+b=5.234 c=23.775 d=29.59 x=360 k=x*250
+
+// This line calculates the cosine of :i and puts the result into :o
+i=abs(:i%x-180)-90 o=b*i+((d*i^5)/k-c*i^3)/k :o=(o+o%0.3)/300

Reference/Durability.yolol

@@ -0,0 +1,8 @@
+// Durability Monitor - :Info = screen name :DurabilityErrors-screen
+tm=20 if :Info=="" AND :DurabilityErrors>0 then goto2 else end goto1
+:Info="\nDurability Error!"
+if td==tm then td=0 goto4 else td++ end goto3
+:Info="\nRe-\ndistribute the heavy ore in the storage."
+if td==tm then td=0 goto6 else td++ end goto5
+:Info="\nOr check the ship for damage."
+if td==tm then td=0 :Info="" goto2 else td++ end goto7

Reference/EGOTech/bugger/CHANGELOG.md

@@ -0,0 +1,27 @@
+# Changelog
+
+## v1.0.3 (Current) - 27/12/2022
+
+- Added Discord link to help chip
+- Added cruise safety chip
+- Added lasers safety chip
+- Added missing redundant ducts
+- Added some missing small plates
+- Added bolts to entry ramp so strength factor does not drop when open
+- Removed auto `Hover` function which didn't work well enough
+- Added side "feelers"
+
+## v1.0.2 - 05/11/2022
+
+- Piped six heat sinks that were not piped
+- Removed now 12 redundant heat sinks
+
+## v1.0.1 - 08/10/2022
+
+- Added "feelers" to keep ship in hover mode while mining
+- Fixed `Shutdown` buttons' button style
+- Moved pilot seat slightly forward
+
+## v1.0.0 - 03/10/2022
+
+- Initial release

Reference/EGOTech/bugger/FEATURES.md

@@ -0,0 +1,27 @@
+# Features
+
+- 448 ore crates
+- Standard Cruise function
+- Turtle and Sloth functions with adjustable rates
+- Transponder system with ping function
+- Separate mining seat for mining operations with view of lasers and ground
+- Row of 10 mining lasers that sweep from side to side
+- Auto mine function that auto advances (with adjustable thrust and speed) ship for easy mining
+- "Feelers" to keep ship in hover mode while mining
+- Four ore collectors
+- Two external and three internal resource bridges
+- Auto generator rate script with adjustable minimum rate
+- 36 T3 generators with 36 T2 enhancers fueled by 12 T3 fuel chambers and 24 spare rods on racks
+- Radiators and heat sinks that provide more than adequate cooling
+- Eight large propellant tanks with 96,000,000 units of propellant
+- Propellant time and fuel time panels
+- 182 batteries
+- 20 T2 box and 80 T2 triangle thrusters providing forward thrust
+- 32 T2 triangle thrusters providing braking thrust
+- 104 T2 triangle thrusters for maneuvers, with extra thrust upwards
+- Basic crafting bench to craft refills plus the tools and advanced bench
+- Speedometer
+- Timer panel
+- Odometer panel
+- Many extra slots for YOLOL or memory chips
+- Top speed of 100m/s when empty

Reference/EGOTech/bugger/README.md

@@ -0,0 +1,15 @@
+# Bugger by EGOTech
+
+[![CC BY-NC-SA 4.0](https://img.shields.io/badge/License-CC%20BY--NC--SA%204.0-lightgrey.svg)](http://creativecommons.org/licenses/by-nc-sa/4.0/)
+
+## For Bugger information and download, see the [ship page](https://starbase.egotech.space/ships/bugger)
+
+[![EGOTech Discord](https://discordapp.com/api/guilds/1013328685564178472/widget.png?style=banner2)](https://discord.gg/BKwVGvncmN)
+
+## Changelog
+
+View changelog [here](CHANGELOG.md)
+
+## Designed by EGOTech
+
+![EGOTech](../others/egotech/logos/egotech_logo_light.png)

Reference/EGOTech/bugger/USAGE.md

@@ -0,0 +1,110 @@
+# Usage
+
+To enter the ship, there is a button on bottom of the ship that will open `Hatch`. Once inside you can also open and close the cockpit glass `Canopy`. Buttons for these are available in the pilot left side consoles.
+
+## Flying the Ship
+
+![Pilot Center Console](https://github.com/EGO-Tech/starbase-ships/raw/main/bugger/images/pilot_center_console.jpg)
+
+The left lever on the center console controls backwards thrust (braking) and the right lever controls forward thrust.
+
+<nord-table>
+
+| Interface | Function |
+|---|---|
+| `Speed` | Current speed in metres per second. |
+| `ForwardThrust` | Current forward thrust, maximum of 10,000 units |
+| `Throttle` | Current throttle level, maximum of 100 percent |
+| `Cruise` | Activates cruise control, forward thrust will not reset to zero unless turned down. |
+| `Turtle` | Activates turtle mode which sets forward thrust to a maximum limit of `TurtleRate` of full thrust. |
+| `Sloth` | Activates the low sensitvity mode of pitch and yaw by limiting thrust. Use the `Sensitivity` switch to set the maximum thrust rate of sloth mode.|
+| `Aim` | Reduces the response time of key presses for pitch and yaw. |
+| `Guide`, `Hover Distance`, `FrontRight`, `FrontLeft`, `BackRight` & `BackLeft` | `Guide` activates rangefinders at each corner of the base of the ship. Each repsective corner shows distance to the ground. `Red` warning lights flash when ground is less that `Hover Distance`. |
+| `Range` & `Distance` | Activates forward rangefinders, with `Distance` showing distance to object detected by center rangefinder. |
+| `Mine`, `Advance`, `Advance Thrust` & `Advance Time` | Mining controls. See [Mining](#mining). |
+| `SafeZone` | Whether current location is in the safe zone. |
+| `StrengthFactor` | Current strength of ship. May fluctuate as ore crates are filled. Anything below 1.0 means ship is damaged. |
+| Transponder `Toggle` & `Ping` | Transponder controls, `Toggle` turns on and off ship transponder while `Ping` will activate transponder for three seconds |
+| `Timer` | See [Timer](#timer). |
+| `Odometer` | See [Odometer](#odometer). |
+
+</nord-table>
+
+<nord-banner variant="warning">
+
+**NOTE:** For safety, firing full braking thrust will deactivate `Cruise`.
+
+</nord-banner>
+
+## Managing Power and Fuel
+
+![Pilot Right Console](https://github.com/EGO-Tech/starbase-ships/raw/main/bugger/images/pilot_right_console.jpg)
+
+<nord-table>
+
+| Interface | Function |
+|---|---|
+| `Propellant` | Total propellant remaining in propellant tanks, maximum of 96,000,000 units. |
+| `PropTime` | Time and distance remaining of propellant based on current usage. Distance is calculated from speed. |
+| `FuelTime` | Time and distance remaining of fuel based on current usage. Distance is calculated from speed. |
+| `WithBackup` | Same as FuelTime but takes into account backup rods available. Use the switch for `Backup Rods` to set the number of backup rods available. As standard there are 24 extra rods. |
+| `Fuel Rod 1` to `Fuel Rod 12` | Fuel remaining on fuel rods in individual fuel chambers, maximum of 300,000 units for each. |
+| `Generator` | Current generator rate. |
+| `Min Gen` & `Min Generator Limit` | Toggle and sets minimum generator rate. See [Managing Power](#managing-power). |
+| `Shutdown` | Will turn off all fuel chambers thus shutting down generators. |
+| `Battery` | Shows current battery charge of the batteries, maximum of 10,000 units. |
+| `HeatTransferRate` | Current heat transfer rate of the heat sinks, maximum of 100%. |
+| `Flow In` & `Flow Out` | Toggle flow modes of resource bridges. See [Refueling Propellant](#refueling-propellant). |
+| `Lights` | Turns on and off internal lights. |
+| `Canopy` | Opens or closes glass canopy. |
+| `Hatch` | Opens or closes ship entry hatch. |
+
+</nord-table>
+
+### Managing Power
+
+By default the generator will only run and ramp up when the batteries need charging so there is minimum management needed. But you can set a minimum generate rate by setting the `Min Generator Limit` value using the switch for the minimum rate and turning on `Min Gen`.
+
+### Refueling Propellant
+
+All four resource bridges can be used for refuelling propellant. To refuel from another ship, turn off `Flow Out` on the pilot right side console and leave `Flow In` turned on. Then connect a resource bridge to the other ship. To refuel another ship, do the opposite, `Flow Out` turned on and `Flow In` turned off.
+
+Remember to turn `Flow In` and `Flow Out` back on if you are using the Endo to collect ore via any of the ship's resource bridges.
+
+## Mining
+
+![Mining Console](https://github.com/EGO-Tech/starbase-ships/raw/main/bugger/images/mining_console.jpg)
+
+Activate `Lasers` to turn on the mining lasers which will automatically sweep from side to side. Activating `Advance` will slowly move the ship forward based on `Advance Time` and `Advance Thrust`. Adjust `Advance Time` (period to wait before each advance in seconds) and `Advance Thrust` (amount of forward thrust when advancing) if needed.
+
+<nord-banner variant="info">
+
+**TIP:** Increase `Advance Thrust` if needed as the ship gains more mass from filling up.
+
+</nord-banner>
+
+`Collect` turns on the four ore collectors.
+
+`Mine` will activate automated mining, which will activate `Lasers`, `Advance` and `Collect`.
+
+<nord-banner variant="info">
+
+**TIP:** Turn on `Min Gen` and allow the generators to ramp up before starting to mine. Continous use of the lasers and collectors at the same time requires a `Min Generator Limit` of around 85%.
+
+</nord-banner>
+
+<nord-banner variant="warning">
+
+**NOTE:** For safety, lasers will turn off if the total fuel is less that 2,000 units.
+
+</nord-banner>
+
+## Other Stuff
+
+### Timer
+
+On the pilot center console there is a `Timer` panel which acts as a timer. It will run when the ship is active and show total time in years, weeks, days, hours, minutes and seconds. To reset the timer, hold down the `Reset Timer` button on the pilot left console.
+
+### Odometer
+
+On the pilot right console there is a `Odometer` panel which will keep track of the ship's estimated flight distance based on speed. To reset the trip odometer, hold down the `Odometer` `Reset Trips` button on the pilot left console.