Behemoth MK2 YOLOL

Behemoth/MK 2/Left/Blue 1.YOLOL

@@ -0,0 +1,20 @@
+:rw=:1r :rwn=-:1r :sw=:1s :swn=-:1s goto:cp
+:rw=:2r :rwn=-:2r :sw=:2s :swn=-:2s goto:cp
+:rw=:3r :rwn=-:3r :sw=:3s :swn=-:3s goto:cp
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu

Behemoth/MK 2/Left/Blue 2.YOLOL

@@ -0,0 +1,20 @@
+:PR="F" :fw=:1f :bw=:1b :pw=:1p :pwn=-:1p :yw=:1y :ywn=-:1y goto:cp
+:PR="M" :fw=:2f :bw=:2b :pw=:2p :pwn=-:2p :yw=:2y :ywn=-:2y goto:cp
+:PR="S" :fw=:3f :bw=:3b :pw=:3p :pwn=-:3p :yw=:3y :ywn=-:3y goto:cp
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu

Behemoth/MK 2/Left/Blue 3.YOLOL

@@ -0,0 +1,20 @@
+a=(:cp*6)-(:cs-1) ifa!=1 thengotoa end :1s+=(:1s<100)*5 :iv=-1 goto1
+a=(:cp*6)-(:cs-1) ifa!=2 thengotoa end :1r+=(:1r<100)*5 :iv=-1 goto2
+a=(:cp*6)-(:cs-1) ifa!=3 thengotoa end :1y+=(:1y<100)*5 :iv=-1 goto3
+a=(:cp*6)-(:cs-1) ifa!=4 thengotoa end :1p+=(:1p<100)*5 :iv=-1 goto4
+a=(:cp*6)-(:cs-1) ifa!=5 thengotoa end :1b+=(:1b<100)*5 :iv=-1 goto5
+a=(:cp*6)-(:cs-1) ifa!=6 thengotoa end :1f+=(:1f<100)*5 :iv=-1 goto6
+a=(:cp*6)-(:cs-1) ifa!=7 thengotoa end :2s+=(:2s<100)*5 :iv=-1 goto7
+a=(:cp*6)-(:cs-1) ifa!=8 thengotoa end :2r+=(:2r<100)*5 :iv=-1 goto8
+a=(:cp*6)-(:cs-1) ifa!=9 thengotoa end :2y+=(:2y<100)*5 :iv=-1 goto9
+a=(:cp*6)-(:cs-1) ifa!=10 thengotoa end :2p+=(:2p<100)*5 :iv=-1 goto10
+a=(:cp*6)-(:cs-1) ifa!=11 thengotoa end :2b+=(:2b<100)*5 :iv=-1 goto11
+a=(:cp*6)-(:cs-1) ifa!=12 thengotoa end :2f+=(:2f<100)*5 :iv=-1 goto12
+a=(:cp*6)-(:cs-1) ifa!=13 thengotoa end :3s+=(:3s<100)*5 :iv=-1 goto13
+a=(:cp*6)-(:cs-1) ifa!=14 thengotoa end :3r+=(:3r<100)*5 :iv=-1 goto14
+a=(:cp*6)-(:cs-1) ifa!=15 thengotoa end :3y+=(:3y<100)*5 :iv=-1 goto15
+a=(:cp*6)-(:cs-1) ifa!=16 thengotoa end :3p+=(:3p<100)*5 :iv=-1 goto16
+a=(:cp*6)-(:cs-1) ifa!=17 thengotoa end :3b+=(:3b<100)*5 :iv=-1 goto17
+a=(:cp*6)-(:cs-1) ifa!=18 thengotoa end :3f+=(:3f<100)*5 :iv=-1 goto18
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu

Behemoth/MK 2/Left/Blue 4.YOLOL

@@ -0,0 +1,20 @@
+a=(:cp*6)-(:cs-1) ifa!=1 thengotoa end :1s-=(:1s>10)*5 :dv=-1 goto1
+a=(:cp*6)-(:cs-1) ifa!=2 thengotoa end :1r-=(:1r>5)*5 :dv=-1 goto2
+a=(:cp*6)-(:cs-1) ifa!=3 thengotoa end :1y-=(:1y>5)*5 :dv=-1 goto3
+a=(:cp*6)-(:cs-1) ifa!=4 thengotoa end :1p-=(:1p>5)*5 :dv=-1 goto4
+a=(:cp*6)-(:cs-1) ifa!=5 thengotoa end :1b-=(:1b>5)*5 :dv=-1 goto5
+a=(:cp*6)-(:cs-1) ifa!=6 thengotoa end :1f-=(:1f>5)*5 :dv=-1 goto6
+a=(:cp*6)-(:cs-1) ifa!=7 thengotoa end :2s-=(:2s>10)*5 :dv=-1 goto7
+a=(:cp*6)-(:cs-1) ifa!=8 thengotoa end :2r-=(:2r>5)*5 :dv=-1 goto8
+a=(:cp*6)-(:cs-1) ifa!=9 thengotoa end :2y-=(:2y>5)*5 :dv=-1 goto9
+a=(:cp*6)-(:cs-1) ifa!=10 thengotoa end :2p-=(:2p>5)*5 :dv=-1 goto10
+a=(:cp*6)-(:cs-1) ifa!=11 thengotoa end :2b-=(:2b>5)*5 :dv=-1 goto11
+a=(:cp*6)-(:cs-1) ifa!=12 thengotoa end :2f-=(:2f>5)*5 :dv=-1 goto12
+a=(:cp*6)-(:cs-1) ifa!=13 thengotoa end :3s-=(:3s>10)*5 :dv=-1 goto13
+a=(:cp*6)-(:cs-1) ifa!=14 thengotoa end :3r-=(:3r>5)*5 :dv=-1 goto14
+a=(:cp*6)-(:cs-1) ifa!=15 thengotoa end :3y-=(:3y>5)*5 :dv=-1 goto15
+a=(:cp*6)-(:cs-1) ifa!=16 thengotoa end :3p-=(:3p>5)*5 :dv=-1 goto16
+a=(:cp*6)-(:cs-1) ifa!=17 thengotoa end :3b-=(:3b>5)*5 :dv=-1 goto17
+a=(:cp*6)-(:cs-1) ifa!=18 thengotoa end :3f-=(:3f>5)*5 :dv=-1 goto18
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu

Behemoth/MK 2/Left/Blue 5.YOLOL

@@ -0,0 +1,20 @@
+:cp+=(:cp<3)*:np-(:cp>1)*:pp :np=0 :pp=0 goto1
+
+
+
+
+
+
+
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu
+// NP - Next Profile
+// PP - Previus Profile
+// CP - Current Profile
+// 
+// SU - Selection Up
+// SD - Selection Down
+// CS - Current Selection
+// 
+// IV - Increase Value
+// DV - Decrease Value

Behemoth/MK 2/Left/Blue 6.YOLOL

@@ -0,0 +1,20 @@
+:cs+=(:cs<6)*:sd-(:cs>1)*:su :sd=0 :su=0 goto1
+
+
+
+
+
+
+
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu
+// NP - Next Profile
+// PP - Previus Profile
+// CP - Current Profile
+// 
+// SU - Selection Up
+// SD - Selection Down
+// CS - Current Selection
+// 
+// IV - Increase Value
+// DV - Decrease Value

Behemoth/MK 2/Left/Blue 7.YOLOL

@@ -0,0 +1,20 @@
+a="\n" f="FWD: " b="BWD: " p="PTH: " y="YAW: " r="RLL: " s="STF: "
+g="  " h="> " j=a+g k=a+h
+:profile=:PR+k+f+:fw+j+b+:bw+j+p+:pw+j+y+:yw+j+r+:rw+j+s+:sw goto2+:cs
+:profile=:PR+j+f+:fw+k+b+:bw+j+p+:pw+j+y+:yw+j+r+:rw+j+s+:sw goto2+:cs
+:profile=:PR+j+f+:fw+j+b+:bw+k+p+:pw+j+y+:yw+j+r+:rw+j+s+:sw goto2+:cs
+:profile=:PR+j+f+:fw+j+b+:bw+j+p+:pw+k+y+:yw+j+r+:rw+j+s+:sw goto2+:cs
+:profile=:PR+j+f+:fw+j+b+:bw+j+p+:pw+j+y+:yw+k+r+:rw+j+s+:sw goto2+:cs
+:profile=:PR+j+f+:fw+j+b+:bw+j+p+:pw+j+y+:yw+j+r+:rw+k+s+:sw goto2+:cs
+
+
+
+
+
+
+
+
+
+
+// Flight Profile Selector by B00M
+// Credit: Adrian202, DarkyWiiYou, Goodgu

Behemoth/MK 2/Left/Green 1.YOLOL

@@ -0,0 +1,20 @@
+e=19 :sa5=:d8*(:d8>e)+(:dsa*(:d8<e))+:d9*(:d9>e)+(:dsa*(:d9<e)) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// sa(#) = Smart Average, used in DSA
+// e = presset value or bias(?)

Behemoth/MK 2/Left/Green 2.YOLOL

@@ -0,0 +1,20 @@
+e=19 :sa4=:d6*(:d6>e)+(:dsa*(:d6<e))+:d7*(:d7>e)+(:dsa*(:d7<e)) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// sa(#) = Smart Average, used in DSA
+// e = presset value or bias(?)

Behemoth/MK 2/Left/Green 3.YOLOL

@@ -0,0 +1,20 @@
+e=19 :sa3=:d4*(:d4>e)+(:dsa*(:d4<e))+:d5*(:d5>e)+(:dsa*(:d5<e)) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// sa(#) = Smart Average, used in DSA
+// e = presset value or bias(?)

Behemoth/MK 2/Left/Green 4.YOLOL

@@ -0,0 +1,20 @@
+e=19 :sa2=:d2*(:d2>e)+(:dsa*(:d2<e))+:d3*(:d3>e)+(:dsa*(:d3<e)) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// sa(#) = Smart Average, used in DSA
+// e = presset value or bias(?)

Behemoth/MK 2/Left/Green 5.YOLOL

@@ -0,0 +1,20 @@
+e=19 :sa1=:d0*(:d0>e)+(:dsa*(:d0<e))+:d1*(:d1>e)+(:dsa*(:d1<e)) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// sa(#) = Smart Average, used in DSA
+// e = presset value or bias(?)
+
+

Behemoth/MK 2/Left/Green 6.YOLOL

@@ -0,0 +1,20 @@
+:dsa=(:sa1+:sa2+:sa3+:sa4+:sa5)/10 goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// dsa = Distance smart average
+// sa(#) = The clamped and combined values of the range finders 
+// essentially making DSA an average of the range finders, removing
+// outliers to prevent ore catchup.

Behemoth/MK 2/Left/Purple 1.YOLOL

@@ -0,0 +1,20 @@
+:calibrate=1
+f=0.8 r=1 goto2+:al
+:frp=(:gp<-r)*f-(:gp>r)*f-:gp :frr=(:gr<-r)*f-(:gr>r)*f-:gr
+:frp=0 :frr=0 goto3*:al
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Left/Purple 2.YOLOL

@@ -0,0 +1,20 @@
+ta=:Hover m=10 a=:H da=ta-a w=da/8 goto1+:HVR
+sud=a-oa oa=a d=w-sud :FcuUpDown=(d*(a<999)*(a>0.1)*m)*(:h<50) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Left/Purple 3.YOLOL

@@ -0,0 +1,20 @@
+:h1=:HFL :h1-=(:h1-:HFR)*(:h1>:HFR) :h1-=(:h1-:HBL)*(:h1>:HBL) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Left/Purple 4.YOLOL

@@ -0,0 +1,20 @@
+:h=:h1 :h-=(:h-:HBR)*(:h>:HBR) :HoverT=((:Hover-:h)*:hvr) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Left/Red 1.YOLOL

@@ -0,0 +1,20 @@
+goto1+:estop
+:crwl=0 :stp=0 :gud=0 :mm=0 :ml=0 :clct=0 :timer=0 :tl=0 goto1
+
+
+
+
+
+
+
+
+
+
+// :crfl = Emergency RF On
+// :crfd = Emergency RF Distance
+// :crwl = Crawl Button
+// :cvg = Mining Laser Converge Button
+// :guide = Trench Guide
+// :bst = Generator Boost Button
+// :ml = Mining Lasers
+// :clct = Collector On Button

Behemoth/MK 2/Left/Red 2.YOLOL

@@ -0,0 +1,20 @@
+:szp=(:szp*:sz) goto1+(:szp*:sz)
+:transponder=1 goto2+(c++>5)
+:transponder=0 c=0
+if :sz==0 then :estop=1 goto5end goto4*:szp
+:FCUBackward=50*(:sz==0) :szp=0 goto5*(:sz==0)
+
+
+
+
+
+
+    
+
+
+
+
+
+// :szp = SafeZone Protection Button
+// :sz = Renamed "insideSafeZone" field from transponder
+// :estop = Emergency Stop (shuts down all mining systems)

Behemoth/MK 2/Left/mem1.MEMORY

@@ -0,0 +1,10 @@
+1f = 100
+1b = 100
+1p = 40
+1y = 60
+1r = 60
+1s = 100
+ChipField7 = 0
+CS = 1
+CP = 1
+PR = "F"

Behemoth/MK 2/Left/mem2.MEMORY

@@ -0,0 +1,10 @@
+2f = 60
+2b = 60
+2p = 30
+2y = 40
+2r = 40
+2s = 60
+ChipField7 = 0
+ChipField8 = 0
+ChipField9 = 0
+ChipField10 = 0

Behemoth/MK 2/Left/mem3.MEMORY

@@ -0,0 +1,10 @@
+3f = 30
+3b = 30
+3p = 15
+3y = 20
+3r = 20
+3s = 30
+ChipField7 = 0
+ChipField8 = 0
+ChipField9 = 0
+ChipField10 = 0

Behemoth/MK 2/Right/Green 1.YOLOL

@@ -0,0 +1,20 @@
+a=1000 b=60 c=3600
+rt="Infinite" rt=(:fuel)/(r-(:fuel)) r=(:fuel)
+h=rt/c/a*a m=(rt-h*c)/b/a*a rt=h+"h "+m+"m"
+pt="Infinite" pt=:propellant/(p-:propellant) p=:propellant
+h=pt/c/a*a m=(pt-h*c)/b/a*a pt=h+"h "+m+"m"
+:gentime="\n"+rt+"\n\n\n\nPropTime:\n"+pt goto2
+
+
+
+
+
+
+
+
+
+
+
+/// :fuel = Fuel Chamber Fuel
+/// :propellant = GasNetworkStoredResource
+/// :gentime = Progress Pannel

Behemoth/MK 2/Right/Green 2.YOLOL

@@ -0,0 +1,20 @@
+:gurl=((100-:bat/100)+(:mm*75)) :speed=:spd goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+/// :gurl = Generator Unit Rate Limit
+/// :bat = Slave Battery
+/// :bst = Generator Boost Button
+/// :rdy = Mining Laser Ready BUtton
+/// :generator = Generator

Behemoth/MK 2/Right/Green 3.YOLOL

@@ -0,0 +1,20 @@
+:timeremaining=0 a=0 goto1+:timer
+:timeremaining=:sleep-(a/300) goto(2+(a++>(:sleep*300)))*:timer
+:estop=1 a=0 :timer=0 :timeremaining=0 goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Right/Green 4.YOLOL

@@ -0,0 +1,20 @@
+:crs=((:cruise==0)*5) :fuel=:f1+:f2 goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+/// :crs = Cruise Button
+/// :cruise = Cruise Lever Name

Behemoth/MK 2/Right/Green 5.YOLOL

@@ -0,0 +1,20 @@
+:rdy=:mm :rdyc=0+(:gen>=75)*2 :rdyb=1-(:gen>=75) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Right/Orange 1.YOLOL

@@ -0,0 +1,20 @@
+d=5 goto1+:stp
+a=:crawlspeed
+:crawlspeed=100
+c=0 :crwlf=100*(:spd<0.1) goto((4+(:spd>0.1))*:stp)+((:stp==0)*8)
+:crwlb=10
+goto6+(:spd<0.1)+((:stp==0)*2)
+goto7-((c++>d)*3)
+:crawlspeed=a goto1
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Right/Orange 2.YOLOL

@@ -0,0 +1,20 @@
+:crawlspeed=15 
+goto2+:crwl
+:crwlf=100 :crwlb=400*(:avg-:ta)*(1+(:md-:dsa)) goto3*:crwl
+
+
+
+
+
+
+
+
+
+// :crawlspeed = Dynamic Crawl Speed
+// :crwl = Auto-Crawl Button
+// :crwlf = Crawl Forward Lever
+// :crwlb = Crawl Backward Lever
+// :avg = Average Speed
+// :ta = Target Average Speed
+// :md = Mining Depth
+// :dsa = Distance Smart Average

Behemoth/MK 2/Right/Orange 3.YOLOL

@@ -0,0 +1,20 @@
+goto1+:crwl
+:crawlspeed=:crawlspeed-(((:avg-:ta)*(:spd>0.1)*(:spd<0.2))) goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :crawlspeed = Dynamic Crawl Speed
+// :avg = Average Speed
+// :ta = Target Average Speed
+// :spd = Speedometer Speed

Behemoth/MK 2/Right/Orange 4.YOLOL

@@ -0,0 +1,20 @@
+t=100 i=1 c=0 goto(1+(:spd==0))*:crwl
+goto(2+(c++>t)-((:spd>0)*2))*:crwl
+:crawlspeed+=i c=0 goto1
+
+
+
+
+
+
+
+
+
+
+// t = Delay on how long to wait before increasing CrawlSpeed
+// i = Amount to increase CrawlSpeed
+// :dsa = Distance Smart Average
+// :md = Mining Depth
+// :spd = Speedometer Speed
+// :crwl = Auto-Crawl Butto
+// :crawlspeed = Dynamic Crawl Speed

Behemoth/MK 2/Right/Orange 5.YOLOL

@@ -0,0 +1,20 @@
+x=10 y=x-1 :ts=0.137
+s=:spd :avg=a a=(a*y+s)/x :ta=:ts*(:dsa/:md) goto2
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// x = Amount of linereads to average speed
+// :spd = Speedometer Speed
+// :avg = Average Speed

Behemoth/MK 2/Right/Orange 6.YOLOL

@@ -0,0 +1,20 @@
+goto1+:am
+:mm=1 goto(2+(:gen>=75))*:am
+:ml=1 :clct=1 goto(3+(w++>50))*:am
+w=0 :crwl=1 :am=0 goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

Behemoth/MK 2/Right/Orange 7.YOLOL

@@ -0,0 +1,20 @@
+p=:cp goto1+:mm
+:cp=3  goto2+(:mm==0)
+:cp=p goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :mm = Mining Mode Button
+// :cp = Current Profile
+// p = Stored Current Profile Value

Behemoth/MK 2/Right/White 1.YOLOL

@@ -0,0 +1,20 @@
+mn=5 mx=100 stp=5 if :csd then goto2end if :csi then goto3end goto1
+a=(:crawlspeed-stp)<mn :crawlspeed=(:crawlspeed-stp)*(1-a)+mn*a goto1
+a=(:crawlspeed+stp)>mx :crawlspeed=(:crawlspeed+stp)*(1-a)+mx*a goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :crawlspeed = Crawl Speed Multiplier
+// :csi = Crawp Speed Increase Button
+// :csd = Crawp Speed Decrease Button

Behemoth/MK 2/Right/White 2.YOLOL

@@ -0,0 +1,20 @@
+mn=10 mx=90 stp=10 if:sld then goto2end if:sli then goto3end goto1
+a=(:sleep-stp)<mn :sleep=(:sleep-stp)*(1-a)+mn*a goto1
+a=(:sleep+stp)>mx :sleep=(:sleep+stp)*(1-a)+mx*a goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :sleep = Sleep Timer
+// :sli = Sleep Increase Button
+// :sld = Sleep Height Decrease Button

Behemoth/MK 2/Right/White 3.YOLOL

@@ -0,0 +1,20 @@
+mn=2 mx=50 stp=1 if:hhd then goto2end if:hhi then goto3end goto1
+a=(:hover-stp)<mn :hover=(:hover-stp)*(1-a)+mn*a goto1
+a=(:hover+stp)>mx :hover=(:hover+stp)*(1-a)+mx*a goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :hover = Hover Height
+// :hhi = Hover Height Increase Button
+// :hhd = Hover Height Decrease Button

Behemoth/MK 2/Right/White 4.YOLOL

@@ -0,0 +1,20 @@
+mn=.1 mx=.3 stp=.001 if :tsd then goto2end if :tsi then goto3end goto1
+a=(:ts-stp)<mn :ts=(:ts-stp)*(1-a)+mn*a goto1
+a=(:ts+stp)>mx :ts=(:ts+stp)*(1-a)+mx*a goto1
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+// :depth = Shortest RF Depth
+// :mdi = Mining Depth Increase Button
+// :mdd = Mining Depth Decrease Button

Behemoth/MK 2/Right/mem1.MEMORY

@@ -0,0 +1,10 @@
+h = 0
+h1 = 0
+avg = 0
+ta = 0
+e = 0
+gurl = 0
+dsl = 22
+tio = 1
+ChipField9 = 0
+ChipField10 = 0

Behemoth/MK 2/Right/mem2.MEMORY

@@ -0,0 +1,10 @@
+md = 22
+sa1 = 0
+sa2 = 0
+sa3 = 0
+sa4 = 0
+sa5 = 0
+dsa = 0
+mo = 0
+as = 0
+os = 0

Behemoth/MK 2/Right/mem3.MEMORY

@@ -0,0 +1,9 @@
+frp = 0
+frr = 0
+ts = 0.137
+generator = 100
+avgta = 0
+hfl = 0
+hfr = 0
+hbl = 0
+hbr = 0

Behemoth/MK 2/Right/mem4.MEMORY

@@ -0,0 +1,10 @@
+FcuRotationalPitch = 0
+FcuRotationalRoll = 0
+TargetSpeed = 0
+gen = 100
+AverageSpeed = 0
+TargetAverage = 0
+FrontLeftHeight = 0
+FrontRightHeight = 0
+RearLeftHeight = 0
+RearRightHeight = 0